verifyAssertionsOfThePaper -- print commands to verify the assertions of the paper

i1 : verifyAssertionsOfThePaper(0)

///
--------------------------------------------------------------------------
-- Theorem 2.2                                                          --
-- We construct a curve C of genus 10 and bidegree (6,10) in P^1xP^2    --
-- by double liaison, as described in the paper. We verify step-by-step --
-- all the assertions of the paper. As a consequence, the projection    --
-- C --> P^2 yields a general element of W^2_{10,10}, which has a Serre --
-- dual model a general element of W^1_{10,8}.                          --
--------------------------------------------------------------------------
p=32009; -- a prime number
Fp=ZZ/p; -- a prime field
S=Fp[x_0,x_1,y_0..y_2,Degrees=>{2:{1,0},3:{0,1}}];
-- Cox-ring of P^1 x P^2
m=ideal basis({1,1},S);
-- On P1xP2, we start  with a rational curve of degree 4 together
-- with 5 general lines. Call C'' their union.
ICrat=ideal random(S^1,S^{2:{-2,-1}});
ICratSat=saturate(ICrat,m);
ILines=apply(5,i->ideal random(S^1,S^{{ -1,0},{0,-1}}));
C''=saturate(intersect(ILines|{ICratSat}),m);
-- We choose random forms in the ideal of C'' of bidegree (5,2) 
-- that define the complete intersection Y' and compute the 
-- saturated ideal C' of the residual curve 
fY'={{5,2},{5,2}};
Y'=ideal(gens C'' * random(source gens C'',S^(-fY')));
time C'=Y':(C''); -- about 12 seconds
C'=saturate(C',m);
-- We check that C' is smooth of bidegree (3,11) and that meets C''
-- only in ordinary double points.
time isSmooth(C') -- about 47 seconds
multidegree C'
time isOrdDoublePoints(Y') -- about 86 seconds
-- We check that C' is of maximal rank in bidegree (b,2) for any
-- b and that it is contained in two transversal hypersurfaces
-- of bidegree (3,3), (4,3) respectively
tally degrees ideal mingens gb C'
-- We choose random forms in the ideal of C' of bidegree (3,3), (4,3) 
-- that define the complete intersection Y and compute the 
-- saturated ideal C of the residual curve 
fY={{3,3},{4,3}};
Y=ideal(gens C' * random(source gens C',S^(-fY)));
time C=Y:(C'); -- about 29 seconds
C=saturate(C,m);
-- We check that C' is smooth of bidegree (6,10) and intersects
-- C'' only in ordinary double points
time isSmooth(C) -- about 61 seconds
multidegree C
time isOrdDoublePoints(Y) -- about 118 seconds
-- We check that C is of maximal rank in bidegree (a,3) for any a
-- and that the planar model of C is a non-degenerate curve of genus 10
-- and degree 10, hence it corresponds to a point in W^2_{10,10}
tally degrees ideal mingens gb C
///


///
--------------------------------------------------------------------------
-- Theorem 3.2                                                          --
-- We construct a curve C of genus 13 and degree 17 in P^6 by liaison   --
-- in P^6 of type (2,2,2,2,2) with respect to a general curve of genus  --
-- 10 and degree 13, which is constructed as described in the paper     --
-- from a general curve of genus 10 together with 3 marked points. We   --
-- verify step-by-step all the assertions of the paper. The Serre dual  --
-- model of C turns out to be a general element of W^1_{13,7}.          --
--------------------------------------------------------------------------
p=32009; -- a prime number
Fp=ZZ/p; -- a prime field
-- We construct a random curve of genus 10 in P^1xP^2 together with 3
-- marked points
time L=randomGenus10CurveNMarkedPoints(p,3); -- about 14 seconds
ID'=L_0; threePoints=L_1;
S=ring ID';
-- We compute the plane model of D' and the embedding D of D' in
-- P^6 via the complete linear system K-P, where P is the divisor
-- of the 3 points previously chosen. By construction, D is a
-- general curve of genus 10 and degree 15 in P^6
R=Fp[x_0..x_6];
P2=Fp[drop(flatten entries vars S,2)];
pi2=map(P2,S);
IDPlane=sub(ID',P2);
RE=P2/IDPlane;
nodes=sub(saturate ideal jacobian ID',P2);
threePoints2=apply(threePoints,p-> trim pi2 p);
KminusD=gens truncate(6,intersect(threePoints2|{nodes}));
emb=map(RE,R,sub(KminusD,RE));
ID=kernel emb;
-- D has genus 10, degree 15 and it is smooth
degree ID, genus ID
jacobianD=jacobian ID;
J=ID;
subsetsSource=subsets(rank source jacobianD,5);
subsetsTarget=subsets(rank target jacobianD,5);
time while codim J < 7 do (
    Ls=first random subsetsSource;
    Lt=first random subsetsTarget;
    J=J+minors(5,(jacobianD)_Ls^Lt);
    ) -- about 23 seconds
codim J==7
-- We take a random complete intersection of type (2,2,2,2,2)
-- containing the curve D and get C via liaison
Y=ideal ((gens ID)*(random(source gens ID, R^{5:-2})));
-- viewHelp
IC=saturate(Y:ID,ideal basis(1,R));
-- We verify that C is a smooth curve of genus 13 and degree 17
degree IC, genus IC
jacobianC=jacobian IC;
J=IC;
subsetsSource=subsets(rank source jacobianC,5);
subsetsTarget=subsets(rank target jacobianC,5);
time while codim J < 7 do (
    Ls=first random subsetsSource;
    Lt=first random subsetsTarget;
    J=J+minors(5,(jacobianC)_Ls^Lt);
    ) -- about 8 seconds
codim J==7
-- We verify that C and D meet only in ordinary double points
INodes=ideal mingens(IC+ID);
jacobianNodes=jacobian INodes;
J=INodes;
subsetsSource=subsets(rank source jacobianNodes,6);
subsetsTarget=subsets(rank target jacobianNodes,6);
time while codim J < 7 do (
    Ls=first random subsetsSource;
    Lt=first random subsetsTarget;
    J=J+minors(6,(jacobianNodes)_Ls^Lt);
    ) -- about 8 seconds
codim J==7
-- We check that C is not contained in any hyperplane. It
-- turns out that C together with its embedding is an
-- element in W^6_{13,17}.
betti IC 
///